See ChangeLog: Sun Feb 28 19:11:00 CET 1999 Werner Koch
[libgcrypt.git] / configure.in
1 dnl
2 dnl Configure template for GNUPG
3 dnl
4 dnl (Process this file with autoconf to produce a configure script.)
5 AC_REVISION($Revision$)dnl
6
7 dnl Must reset CDPATH so that bash's cd does not print to stdout
8 CDPATH=
9
10 AC_INIT(g10/g10.c)
11 AC_CONFIG_AUX_DIR(scripts)
12 AM_CONFIG_HEADER(config.h)
13
14
15 VERSION=`cat $srcdir/VERSION`
16 PACKAGE=gnupg
17 ALL_LINGUAS="de es_ES fr it pl pt_BR ru"
18 static_modules="sha1 md5 rmd160"
19 AC_SUBST(VERSION)
20 AC_SUBST(PACKAGE)
21 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
22 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
23
24 MODULES_IN_CIPHER=`awk '/# MODULES: / { for(i=3;i<=NF;i++) print $i}' \
25                                                 $srcdir/cipher/Makefile.am`
26
27 dnl
28 dnl  Check for random module options
29 dnl
30 dnl  Fixme: get the list of available modules from MODULES_IN_CIPHER
31 dnl         and check agiants this list
32
33 AC_MSG_CHECKING([which static random module to use])
34 AC_ARG_ENABLE(static-rnd,
35     [  --enable-static-rnd=[egd|unix|linux|nonde]  ],
36 [use_static_rnd=$enableval], [use_static_rnd=default] )
37
38 if test "$use_static_rnd" = no; then
39     use_static_rnd=default
40 fi
41
42 case "$use_static_rnd" in
43     egd | linux | unix | none | default )
44       AC_MSG_RESULT($use_static_rnd)
45       ;;
46     * )
47       AC_MSG_RESULT(invalid argument)
48       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
49       ;;
50 esac
51
52 dnl
53 dnl See whether the user wants to disable checking for 7dev/random
54
55 AC_MSG_CHECKING([whether use of /dev/random is requested])
56 AC_ARG_ENABLE(dev-random,
57 [  --disable-dev-random    disable the use of dev random],
58     try_dev_random=$enableval, try_dev_random=yes)
59 AC_MSG_RESULT($try_dev_random)
60
61
62 dnl
63 dnl  Check other options
64 dnl
65
66 AC_MSG_CHECKING([whether use of extensions is requested])
67 AC_ARG_ENABLE(dynload,
68 [  --disable-dynload       disable use of extensions],
69     try_dynload=$enableval, try_dynload=yes)
70 AC_MSG_RESULT($try_dynload)
71
72 AC_MSG_CHECKING([whether assembler modules are requested])
73 AC_ARG_ENABLE(asm,
74 [  --disable-asm           do not use assembler modules],
75      try_asm_modules=$enableval, try_asm_modules=yes)
76 AC_MSG_RESULT($try_asm_modules)
77
78 AC_MSG_CHECKING([whether memory debugging is requested])
79 AC_ARG_ENABLE(m-debug,
80 [  --enable-m-debug        enable debugging of memory allocation],
81 use_m_debug=$enableval, use_m_debug=no)
82 AC_MSG_RESULT($use_m_debug)
83 if test "$use_m_debug" = yes; then
84     AC_DEFINE(M_DEBUG)
85     use_m_guard=yes
86 else
87     AC_MSG_CHECKING([whether memory guard is requested])
88     AC_ARG_ENABLE(m-guard,
89     [  --enable-m-guard        enable memory guard facility],
90     use_m_guard=$enableval, use_m_guard=no)
91     AC_MSG_RESULT($use_m_guard)
92 fi
93 if test "$use_m_guard" = yes ; then
94     AC_DEFINE(M_GUARD)
95 fi
96
97
98 AC_MSG_CHECKING([whether included zlib is requested])
99 AC_ARG_WITH(included-zlib,
100     [  --with-included-zlib    use the zlib code included here],
101 [g10_force_zlib=yes], [g10_force_zlib=no] )
102 AC_MSG_RESULT($g10_force_zlib)
103
104
105 dnl Checks for programs.
106
107 AC_CANONICAL_SYSTEM
108 AC_ARG_PROGRAM
109 AC_PROG_MAKE_SET
110 AM_SANITY_CHECK
111 missing_dir=`cd $ac_aux_dir && pwd`
112 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
113 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
114 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
115 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
116 dnl AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
117 AC_PROG_CC
118 AC_PROG_CPP
119 AC_ISC_POSIX
120 AC_PROG_RANLIB
121 AC_PROG_INSTALL
122 dnl AC_CYGWIN32
123 dnl AM_PROG_LIBTOOL
124
125 MPI_OPT_FLAGS=""
126 if test "$GCC" = yes; then
127     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
128 fi
129
130
131 try_gettext=yes
132 try_gdbm=yes
133 case "${target}" in
134     i386--mingw32)
135         # special stuff for Windoze NT
136         cross_compiling=yes
137         CC="i386--mingw32-gcc"
138         CPP="i386--mingw32-gcc -E"
139         RANLIB="i386--mingw32-ranlib"
140         ac_cv_have_dev_random=no
141         AC_DEFINE(USE_ONLY_8DOT3)
142         AC_DEFINE(HAVE_DRIVE_LETTERS)
143         AC_DEFINE(HAVE_DOSISH_SYSTEM)
144         try_gettext="no"
145         try_gdbm="no"
146         ;;
147     i386-emx-os2)
148         # OS/2 with the EMX environment
149         ac_cv_have_dev_random=no
150         AC_DEFINE(HAVE_DRIVE_LETTERS)
151         AC_DEFINE(HAVE_DOSISH_SYSTEM)
152         try_gettext="no"
153         try_gdbm="no"
154         ;;
155     *-*-hpux*)
156         if test -z "$GCC" ; then
157             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
158         fi
159         ;;
160     *-dec-osf4*)
161         if test -z "$GCC" ; then
162             # Suppress all warnings
163             # to get rid of the unsigned/signed char mismatch warnings.
164             CFLAGS="$CFLAGS -w"
165         fi
166         ;;
167     m68k-atari-mint)
168         ;;
169     *)
170        ;;
171 esac
172
173 AC_SUBST(MPI_OPT_FLAGS)
174
175 GNUPG_CHECK_PIC
176 GNUPG_CHECK_RDYNAMIC
177 if test "$NO_PIC" = yes; then
178     try_dynload=no
179 fi
180
181
182 case "${target}" in
183     i386--mingw32)
184         PRINTABLE_OS_NAME="MingW32"
185         ;;
186     i386-emx-os2)
187         PRINTABLE_OS_NAME="OS/2"
188         ;;
189     *-linux*)
190         PRINTABLE_OS_NAME="GNU/Linux"
191         ;;
192     *)
193         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
194         ;;
195 esac
196 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME")
197
198 dnl  Fixme: Are these the best flags for OpenBSD????
199 case "${target}" in
200     *-openbsd*)
201         NAME_OF_DEV_RANDOM="/dev/srandom"
202         NAME_OF_DEV_URANDOM="/dev/urandom"
203         DYNLINK_MOD_CFLAGS="-shared -rdynamic -fpic -Wl,-Bshareable -Wl,-x"
204         ;;
205     *)
206         NAME_OF_DEV_RANDOM="/dev/random"
207         NAME_OF_DEV_URANDOM="/dev/urandom"
208         DYNLINK_MOD_CFLAGS="-shared $CFLAGS_PIC -lc"
209         ;;
210 esac
211 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM")
212 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM")
213 AC_SUBST(MPI_OPT_FLAGS)
214
215
216 dnl Checks for libraries.
217
218 if test "$try_gettext" = yes; then
219 AM_GNU_GETTEXT
220 fi
221
222 if test "$try_gdbm" = yes; then
223 AC_CHECK_LIB(gdbm,gdbm_firstkey)
224 fi
225
226 dnl Solaris needs -lsocket and -lnsl
227 AC_CHECK_LIB(socket, socket)
228 AC_CHECK_LIB(nsl, gethostbyname)
229
230
231 if test "$try_dynload" = yes ; then
232   AC_CHECK_LIB(dl,dlopen)
233   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
234     AC_DEFINE(USE_DYNAMIC_LINKING)
235     AC_DEFINE(HAVE_DL_DLOPEN)
236     DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
237     use_gnupg_extensions=yes
238   else
239     AC_CHECK_LIB(c,dlopen)
240     if test "$ac_cv_lib_c_dlopen" = "yes"; then
241       AC_DEFINE(USE_DYNAMIC_LINKING)
242       AC_DEFINE(HAVE_DL_DLOPEN)
243       DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
244       dnl fixme: this is probably false but it should
245       dnl work for freebsd
246       AC_DEFINE(DLSYM_NEEDS_UNDERSCORE)
247       use_gnupg_extensions=yes
248 dnl else
249 dnl
250 dnl  DLD is not ready for use. So I better disable this test
251 dnl
252 dnl    AC_CHECK_LIB(dld,dld_link)
253 dnl    if test "$ac_cv_lib_dld_dld_link" = "yes"; then
254 dnl      AC_DEFINE(USE_DYNAMIC_LINKING)
255 dnl      AC_DEFINE(HAVE_DLD_DLD_LINK)
256 dnl      DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
257 dnl      use_gnupg_extensions=yes
258 dnl    fi
259     fi
260   fi
261 else
262   AC_MSG_CHECKING(for dynamic loading)
263   DYNLINK_LDFLAGS=
264   DYNLINK_MOD_CFLAGS=
265   use_gnupg_extensions=no
266   AC_MSG_RESULT(has been disabled)
267 fi
268
269 AM_CONDITIONAL(ENABLE_GNUPG_EXTENSIONS, test "$use_gnupg_extensions" = yes )
270 AC_SUBST(DYNLINK_LDFLAGS)
271 AC_SUBST(DYNLINK_MOD_CFLAGS)
272
273
274 dnl Checks for header files.
275 AC_HEADER_STDC
276 AC_CHECK_HEADERS(unistd.h)
277
278
279 dnl Checks for typedefs, structures, and compiler characteristics.
280 AC_C_CONST
281 AC_C_INLINE
282 AC_TYPE_SIZE_T
283 AC_TYPE_SIGNAL
284 AC_DECL_SYS_SIGLIST
285
286 GNUPG_CHECK_ENDIAN
287
288
289 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
290 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
291 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
292 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
293 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
294
295 AC_CHECK_SIZEOF(unsigned short, 2)
296 AC_CHECK_SIZEOF(unsigned int, 4)
297 AC_CHECK_SIZEOF(unsigned long, 4)
298
299 if test "$ac_cv_sizeof_unsigned_short" = "0" \
300    || test "$ac_cv_sizeof_unsigned_int" = "0" \
301    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
302     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
303 fi
304
305
306
307 dnl Checks for library functions.
308 AC_FUNC_VPRINTF
309 AC_CHECK_FUNCS(strerror stpcpy strlwr tcgetattr rand strtoul mmap)
310 AC_CHECK_FUNCS(memmove gettimeofday getrusage gethrtime setrlimit)
311 AC_CHECK_FUNCS(memicmp atexit raise getpagesize strftime)
312
313 GNUPG_CHECK_MLOCK
314
315 GNUPG_CHECK_IPC
316 if test "$ac_cv_header_sys_shm_h" = "yes"; then
317   AC_DEFINE(USE_SHM_COPROCESSING)
318 fi
319
320 dnl check whether we have a random device
321 if test "$try_dev_random" = yes ; then
322 AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
323 [if test -c "$NAME_OF_DEV_RANDOM" && test -c "$NAME_OF_DEV_URANDOM" ; then
324   ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
325 if test "$ac_cv_have_dev_random" = yes; then
326     AC_DEFINE(HAVE_DEV_RANDOM)
327 fi
328 else
329     AC_MSG_CHECKING(for random device)
330     ac_cv_have_dev_random=no
331     AC_MSG_RESULT(has been disabled)
332 fi
333
334
335 dnl
336 dnl Figure out the default linkage mode for cipher modules
337 dnl
338 dnl (We always need a static rmd160)
339 static_modules="$static_modules rmd160"
340 if test "$use_static_rnd" = default; then
341   if test "$ac_cv_have_dev_random" = yes; then
342       static_modules="$static_modules rndlinux"
343   else
344       case "${target}" in
345           i386--mingw32)
346               static_modules="$static_modules rndw32"
347               ;;
348           i386-emx-os2)
349               static_modules="$static_modules rndos2"
350               ;;
351           m68k-atari-mint)
352               static_modules="$static_modules rndatari"
353               ;;
354           *)
355               static_modules="$static_modules rndunix"
356              ;;
357       esac
358   fi
359 else
360   if test "$use_static_rnd" = none; then
361     :
362   else
363     static_modules="$static_modules rnd$use_static_rnd"
364   fi
365 fi
366
367 dnl
368 dnl Parse the modules list and build the list
369 dnl of static and dymically linked modules
370 dnl
371 STATIC_CIPHER_NAMES=""
372 STATIC_CIPHER_OBJS=""
373 DYNAMIC_CIPHER_MODS=""
374 GNUPG_MSG_PRINT([dynamically linked cipher modules:])
375 for name in $MODULES_IN_CIPHER; do
376     x="no"
377     for i in $static_modules; do
378         if test "$name" = "$i" ; then
379             x="yes"
380         fi
381     done;
382     if test $x = yes; then
383         STATIC_CIPHER_NAMES="$STATIC_CIPHER_NAMES $name"
384         STATIC_CIPHER_OBJS="$STATIC_CIPHER_OBJS $name.o"
385     else
386         DYNAMIC_CIPHER_MODS="$DYNAMIC_CIPHER_MODS $name"
387         GNUPG_MSG_PRINT([$name])
388     fi
389 done
390 AC_MSG_RESULT()
391 AC_SUBST(STATIC_CIPHER_OBJS)
392 AC_SUBST(STATIC_CIPHER_NAMES)
393 AC_SUBST(DYNAMIC_CIPHER_MODS)
394
395 dnl
396 dnl And build the constructor file
397 dnl
398
399 test -d cipher || mkdir cipher
400 cat <<EOF >cipher/construct.c
401 /* automatically generated by configure - do not edit */
402
403 EOF
404 GNUPG_MSG_PRINT([statically linked cipher modules:])
405 for name in $STATIC_CIPHER_NAMES; do
406     echo "void ${name}_constructor(void);" >>cipher/construct.c
407     GNUPG_MSG_PRINT([$name])
408 done
409 AC_MSG_RESULT()
410 cat <<EOF >>cipher/construct.c
411
412 void
413 cipher_modules_constructor(void)
414 {
415     static int done = 0;
416     if( done )
417         return;
418     done = 1;
419
420 EOF
421 for name in $STATIC_CIPHER_NAMES; do
422     echo "   ${name}_constructor();" >>cipher/construct.c
423 done
424 echo '}' >>cipher/construct.c
425
426
427
428
429 dnl
430 dnl Figure how to link the cipher modules
431 dnl
432 dnl (form now these are only dynamic)
433 AC_SUBST(STATIC_CIPHER_OBJS)
434 AC_SUBST(DYNAMIC_CIPHER_MODS)
435
436
437
438 dnl setup assembler stuff
439 AC_MSG_CHECKING(for mpi assembler functions)
440 if test -f $srcdir/mpi/config.links ; then
441     . $srcdir/mpi/config.links
442     GNUPG_LINK_FILES($mpi_ln_src, $mpi_ln_dst)
443     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
444     ac_cv_mpi_sflags="$mpi_sflags"
445     ac_cv_mpi_config_done="yes"
446     AC_MSG_RESULT(done)
447 else
448     AC_MSG_RESULT(failed)
449     AC_MSG_ERROR([mpi/config.links missing!])
450 fi
451 MPI_EXTRA_ASM_OBJS=""
452 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
453 GNUPG_MSG_PRINT([mpi extra asm functions:])
454 for i in $ac_cv_mpi_extra_asm_modules; do
455     GNUPG_MSG_PRINT([$i])
456     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
457 done
458 AC_MSG_RESULT()
459 fi
460 AC_SUBST(MPI_EXTRA_ASM_OBJS)
461 MPI_SFLAGS="$ac_cv_mpi_sflags"
462 AC_SUBST(MPI_SFLAGS)
463
464 dnl Do we have zlib? Must do it here because Solaris failed
465 dnl when compiling a conftest (due to the "-lz" from LIBS).
466 if test "$g10_force_zlib" = "yes"; then
467     ZLIBS="../zlib/libzlib.a"
468     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
469     GNUPG_LINK_FILES(zlib/zlib.h, zlib.h )
470     GNUPG_LINK_FILES(zlib/zconf.h, zconf.h )
471 else
472 AC_CHECK_HEADERS(zlib.h)
473 if test "$ac_cv_header_zlib_h" = yes ; then
474     LIBS="$LIBS -lz"
475     ZLIBS=
476     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
477 else
478     ZLIBS="../zlib/libzlib.a"
479     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
480     GNUPG_LINK_FILES(zlib/zlib.h, zlib.h )
481     GNUPG_LINK_FILES(zlib/zconf.h, zconf.h )
482 fi
483 fi
484 AC_SUBST(ZLIBS)
485
486 if echo "$VERSION" | grep '[a-zA-Z]' >/dev/null ; then
487     AC_DEFINE(IS_DEVELOPMENT_VERSION)
488 fi
489
490 GNUPG_DO_LINK_FILES
491
492
493 AC_OUTPUT([
494 Makefile
495 intl/Makefile
496 po/Makefile.in
497 util/Makefile
498 mpi/Makefile
499 cipher/Makefile
500 g10/Makefile
501 doc/Makefile
502 tools/Makefile
503 zlib/Makefile
504 checks/Makefile
505 ])
506
507 dnl *-*wedit:notab*-*  Please keep this as the last line.