Add aarch64 (arm64) mpi assembly
[libgcrypt.git] / mpi / aarch64 / mpih-mul1.S
1 /* ARM64 mul_1 -- Multiply a limb vector with a limb and store the result in
2  *                a second limb vector.
3  *
4  *      Copyright © 2013 Jussi Kivilinna <jussi.kivilinna@iki.fi>
5  *
6  * This file is part of Libgcrypt.
7  *
8  * Libgcrypt is free software; you can redistribute it and/or modify
9  * it under the terms of the GNU Lesser General Public License as
10  * published by the Free Software Foundation; either version 2.1 of
11  * the License, or (at your option) any later version.
12  *
13  * Libgcrypt is distributed in the hope that it will be useful,
14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16  * GNU Lesser General Public License for more details.
17  *
18  * You should have received a copy of the GNU Lesser General Public
19  * License along with this program; if not, see <http://www.gnu.org/licenses/>.
20  *
21  */
22
23 #include "sysdep.h"
24 #include "asm-syntax.h"
25
26 /*******************
27  * mpi_limb_t
28  * _gcry_mpih_mul_1( mpi_ptr_t res_ptr,         x0
29  *                mpi_ptr_t s1_ptr,             x1
30  *                mpi_size_t s1_size,           x2
31  *                mpi_limb_t s2_limb)           x3
32  */
33
34 .text
35
36 .globl _gcry_mpih_mul_1
37 .type  _gcry_mpih_mul_1,%function
38 _gcry_mpih_mul_1:
39         and     x5, x2, #3;
40         mov     x4, xzr;
41
42         cbz     x5, .Large_loop;
43
44 .Loop:
45         ldr     x5, [x1], #8;
46         sub     x2, x2, #1;
47         mul     x9, x5, x3;
48         umulh   x10, x5, x3;
49         and     x5, x2, #3;
50         adds    x4, x4, x9;
51         str     x4, [x0], #8;
52         adc     x4, x10, xzr;
53
54         cbz     x2, .Lend;
55         cbnz    x5, .Loop;
56
57 .Large_loop:
58         ldp     x5, x6, [x1];
59         sub     x2, x2, #4;
60
61         mul     x9, x5, x3;
62         ldp     x7, x8, [x1, #16];
63         umulh   x10, x5, x3;
64         add     x1, x1, #32;
65
66         adds    x4, x4, x9;
67         str     x4, [x0], #8;
68         mul     x11, x6, x3;
69         adc     x4, x10, xzr;
70
71         umulh   x12, x6, x3;
72
73         adds    x4, x4, x11;
74         str     x4, [x0], #8;
75         mul     x13, x7, x3;
76         adc     x4, x12, xzr;
77
78         umulh   x14, x7, x3;
79
80         adds    x4, x4, x13;
81         str     x4, [x0], #8;
82         mul     x15, x8, x3;
83         adc     x4, x14, xzr;
84
85         umulh   x16, x8, x3;
86
87         adds    x4, x4, x15;
88         str     x4, [x0], #8;
89         adc     x4, x16, xzr;
90
91         cbnz    x2, .Large_loop;
92
93 .Lend:
94         mov     x0, x4;
95         ret;
96 .size _gcry_mpih_mul_1,.-_gcry_mpih_mul_1;