Add aarch64 (arm64) mpi assembly
[libgcrypt.git] / mpi / aarch64 / mpih-sub1.S
1 /* ARM64 sub_n -- Subtract two limb vectors of the same length > 0 and store
2  *                sum in a third limb vector.
3  *
4  *      Copyright © 2013 Jussi Kivilinna <jussi.kivilinna@iki.fi>
5  *
6  * This file is part of Libgcrypt.
7  *
8  * Libgcrypt is free software; you can redistribute it and/or modify
9  * it under the terms of the GNU Lesser General Public License as
10  * published by the Free Software Foundation; either version 2.1 of
11  * the License, or (at your option) any later version.
12  *
13  * Libgcrypt is distributed in the hope that it will be useful,
14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16  * GNU Lesser General Public License for more details.
17  *
18  * You should have received a copy of the GNU Lesser General Public
19  * License along with this program; if not, see <http://www.gnu.org/licenses/>.
20  *
21  */
22
23 #include "sysdep.h"
24 #include "asm-syntax.h"
25
26 /*******************
27  *  mpi_limb_t
28  *  _gcry_mpih_sub_n( mpi_ptr_t res_ptr,        x0
29  *                 mpi_ptr_t s1_ptr,            x1
30  *                 mpi_ptr_t s2_ptr,            x2
31  *                 mpi_size_t size)             x3
32  */
33
34 .text
35
36 .globl _gcry_mpih_sub_n
37 .type  _gcry_mpih_sub_n,%function
38 _gcry_mpih_sub_n:
39         and     x5, x3, #3;
40         subs    xzr, xzr, xzr; /* prepare carry flag for sub */
41
42         cbz     x5, .Large_loop;
43
44 .Loop:
45         ldr     x4, [x1], #8;
46         sub     x3, x3, #1;
47         ldr     x11, [x2], #8;
48         and     x5, x3, #3;
49         sbcs    x4, x4, x11;
50         str     x4, [x0], #8;
51         cbz     x3, .Lend;
52         cbnz    x5, .Loop;
53
54 .Large_loop:
55         ldp     x4, x6, [x1], #16;
56         ldp     x5, x7, [x2], #16;
57         ldp     x8, x10, [x1], #16;
58         ldp     x9, x11, [x2], #16;
59         sub     x3, x3, #4;
60         sbcs    x4, x4, x5;
61         sbcs    x6, x6, x7;
62         sbcs    x8, x8, x9;
63         sbcs    x10, x10, x11;
64         stp     x4, x6, [x0], #16;
65         stp     x8, x10, [x0], #16;
66         cbnz    x3, .Large_loop;
67
68 .Lend:
69         cset    x0, cc;
70         ret;
71 .size _gcry_mpih_sub_n,.-_gcry_mpih_sub_n;