Add a bad-case test for the key generation.
[libgcrypt.git] / mpi / pa7100 / mpih-rshift.S
1 /* hppa   rshift
2  *        optimized for the PA7100, where it runs at 3.25 cycles/limb
3  *
4  *      Copyright (C) 1992, 1994, 1998,
5  *                    2001, 2002 Free Software Foundation, Inc.
6  *
7  * This file is part of Libgcrypt.
8  *
9  * Libgcrypt is free software; you can redistribute it and/or modify
10  * it under the terms of the GNU Lesser General Public License as
11  * published by the Free Software Foundation; either version 2.1 of
12  * the License, or (at your option) any later version.
13  *
14  * Libgcrypt is distributed in the hope that it will be useful,
15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17  * GNU Lesser General Public License for more details.
18  *
19  * You should have received a copy of the GNU Lesser General Public
20  * License along with this program; if not, write to the Free Software
21  * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
22  */
23
24
25
26 /*******************
27  * mpi_limb_t
28  * _gcry_mpih_rshift( mpi_ptr_t wp,       (gr26)
29  *                 mpi_ptr_t up,       (gr25)
30  *                 mpi_size_t usize,   (gr24)
31  *                 unsigned cnt)       (gr23)
32  */
33
34         .code
35         .export         _gcry_mpih_rshift
36         .label          _gcry_mpih_rshift
37         .proc
38         .callinfo       frame=64,no_calls
39         .entry
40
41         ldws,ma         4(0,%r25),%r22
42         mtsar           %r23
43         addib,=         -1,%r24,L$r004
44         vshd            %r22,%r0,%r28           ; compute carry out limb
45         ldws,ma         4(0,%r25),%r29
46         addib,<=        -5,%r24,L$rrest
47         vshd            %r29,%r22,%r20
48
49         .label  L$roop
50         ldws,ma         4(0,%r25),%r22
51         stws,ma         %r20,4(0,%r26)
52         vshd            %r22,%r29,%r20
53         ldws,ma         4(0,%r25),%r29
54         stws,ma         %r20,4(0,%r26)
55         vshd            %r29,%r22,%r20
56         ldws,ma         4(0,%r25),%r22
57         stws,ma         %r20,4(0,%r26)
58         vshd            %r22,%r29,%r20
59         ldws,ma         4(0,%r25),%r29
60         stws,ma         %r20,4(0,%r26)
61         addib,>         -4,%r24,L$roop
62         vshd            %r29,%r22,%r20
63
64         .label  L$rrest
65         addib,=         4,%r24,L$rend1
66         nop
67         .label  L$eroop
68         ldws,ma         4(0,%r25),%r22
69         stws,ma         %r20,4(0,%r26)
70         addib,<=        -1,%r24,L$rend2
71         vshd            %r22,%r29,%r20
72         ldws,ma         4(0,%r25),%r29
73         stws,ma         %r20,4(0,%r26)
74         addib,>         -1,%r24,L$eroop
75         vshd            %r29,%r22,%r20
76
77         .label  L$rend1
78         stws,ma         %r20,4(0,%r26)
79         vshd            %r0,%r29,%r20
80         bv              0(%r2)
81         stw             %r20,0(0,%r26)
82         .label  L$rend2
83         stws,ma         %r20,4(0,%r26)
84         .label  L$r004
85         vshd            %r0,%r22,%r20
86         bv              0(%r2)
87         stw             %r20,0(0,%r26)
88
89         .exit
90         .procend
91
92