70dc501e5b4314e7fb1af31b117b0386c5b2ad88
[libksba.git] / m4 / gpg-error.m4
1 # gpg-error.m4 - autoconf macro to detect libgpg-error.
2 # Copyright (C) 2002, 2003, 2004, 2011, 2014, 2018 g10 Code GmbH
3 #
4 # This file is free software; as a special exception the author gives
5 # unlimited permission to copy and/or distribute it, with or without
6 # modifications, as long as this notice is preserved.
7 #
8 # This file is distributed in the hope that it will be useful, but
9 # WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
10 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
11 #
12 # Last-changed: 2018-10-26
13
14
15 dnl AM_PATH_GPG_ERROR([MINIMUM-VERSION,
16 dnl                   [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND ]]])
17 dnl
18 dnl Test for libgpg-error and define GPG_ERROR_CFLAGS, GPG_ERROR_LIBS,
19 dnl GPG_ERROR_MT_CFLAGS, and GPG_ERROR_MT_LIBS.  The _MT_ variants are
20 dnl used for programs requireing real multi thread support.
21 dnl
22 dnl If a prefix option is not used, the config script is first
23 dnl searched in $SYSROOT/bin and then along $PATH.  If the used
24 dnl config script does not match the host specification the script
25 dnl is added to the gpg_config_script_warn variable.
26 dnl
27 AC_DEFUN([AM_PATH_GPG_ERROR],
28 [ AC_REQUIRE([AC_CANONICAL_HOST])
29   gpg_error_config_prefix=""
30   dnl --with-libgpg-error-prefix=PFX is the preferred name for this option,
31   dnl since that is consistent with how our three siblings use the directory/
32   dnl package name in --with-$dir_name-prefix=PFX.
33   AC_ARG_WITH(libgpg-error-prefix,
34               AC_HELP_STRING([--with-libgpg-error-prefix=PFX],
35                              [prefix where GPG Error is installed (optional)]),
36               [gpg_error_config_prefix="$withval"])
37
38   dnl Accept --with-gpg-error-prefix and make it work the same as
39   dnl --with-libgpg-error-prefix above, for backwards compatibility,
40   dnl but do not document this old, inconsistently-named option.
41   AC_ARG_WITH(gpg-error-prefix,,
42               [gpg_error_config_prefix="$withval"])
43
44   if test x"${GPG_ERROR_CONFIG}" = x ; then
45      if test x"${gpg_error_config_prefix}" != x ; then
46         GPG_ERROR_CONFIG="${gpg_error_config_prefix}/bin/gpg-error-config"
47      else
48        case "${SYSROOT}" in
49          /*)
50            if test -x "${SYSROOT}/bin/gpg-error-config" ; then
51              GPG_ERROR_CONFIG="${SYSROOT}/bin/gpg-error-config"
52            fi
53            ;;
54          '')
55            ;;
56           *)
57            AC_MSG_WARN([Ignoring \$SYSROOT as it is not an absolute path.])
58            ;;
59        esac
60      fi
61   fi
62
63   AC_PATH_PROG(GPG_ERROR_CONFIG, gpg-error-config, no)
64   min_gpg_error_version=ifelse([$1], ,1.33,$1)
65   ok=no
66
67   use_gpgrt_config=""
68   if test "$GPG_ERROR_CONFIG" = "no"; then
69     AC_PATH_PROG(GPGRT_CONFIG, gpgrt-config, no)
70     if CC=$CC $GPGRT_CONFIG gpg-error >/dev/null 2>&1; then
71       GPG_ERROR_CONFIG="$GPGRT_CONFIG gpg-error"
72       use_gpgrt_config=yes
73       gpg_error_config_version=`CC=$CC $GPG_ERROR_CONFIG --modversion`
74     fi
75   else
76     gpg_error_config_version=`CC=$CC $GPG_ERROR_CONFIG --version`
77   fi
78   if test "$GPG_ERROR_CONFIG" != "no"; then
79     req_major=`echo $min_gpg_error_version | \
80                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
81     req_minor=`echo $min_gpg_error_version | \
82                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
83     major=`echo $gpg_error_config_version | \
84                sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
85     minor=`echo $gpg_error_config_version | \
86                sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
87     if test "$major" -gt "$req_major"; then
88         ok=yes
89     else
90         if test "$major" -eq "$req_major"; then
91             if test "$minor" -ge "$req_minor"; then
92                ok=yes
93             fi
94         fi
95     fi
96     if test -z "$GPGRT_CONFIG"; then
97       if test "$major" -gt 1 -o "$major" -eq 1 -a "$minor" -ge 33; then
98         AC_PATH_PROG(GPGRT_CONFIG, gpgrt-config, no)
99         GPG_ERROR_CONFIG="$GPGRT_CONFIG gpg-error"
100         use_gpgrt_config=yes
101       fi
102     fi
103   fi
104   AC_MSG_CHECKING(for GPG Error - version >= $min_gpg_error_version)
105   if test $ok = yes; then
106     GPG_ERROR_CFLAGS=`CC=$CC $GPG_ERROR_CONFIG --cflags`
107     GPG_ERROR_LIBS=`CC=$CC $GPG_ERROR_CONFIG --libs`
108     if test -z "$use_gpgrt_config"; then
109       GPG_ERROR_MT_CFLAGS=`CC=$CC $GPG_ERROR_CONFIG $gpg_error_config_args --mt --cflags 2>/dev/null`
110       GPG_ERROR_MT_LIBS=`CC=$CC $GPG_ERROR_CONFIG $gpg_error_config_args --mt --libs 2>/dev/null`
111     else
112       GPG_ERROR_MT_CFLAGS=`CC=$CC $GPG_ERROR_CONFIG --variable=mtcflags 2>/dev/null`
113       GPG_ERROR_MT_CFLAGS="$GPG_ERROR_CFLAGS${GPG_ERROR_CFLAGS:+ }$GPG_ERROR_MT_CFLAGS"
114       GPG_ERROR_MT_LIBS=`CC=$CC $GPG_ERROR_CONFIG --variable=mtlibs 2>/dev/null`
115       GPG_ERROR_MT_LIBS="$GPG_ERROR_LIBS${GPG_ERROR_LIBS:+ }$GPG_ERROR_MT_LIBS"
116     fi
117     AC_MSG_RESULT([yes ($gpg_error_config_version)])
118     ifelse([$2], , :, [$2])
119     if test -z "$use_gpgrt_config"; then
120       gpg_error_config_host=`CC=$CC $GPG_ERROR_CONFIG --host 2>/dev/null || echo none`
121     else
122       gpg_error_config_host=`CC=$CC $GPG_ERROR_CONFIG --variable=host 2>/dev/null || echo none`
123     fi
124     if test x"$gpg_error_config_host" != xnone ; then
125       if test x"$gpg_error_config_host" != x"$host" ; then
126   AC_MSG_WARN([[
127 ***
128 *** The config script "$GPG_ERROR_CONFIG" was
129 *** built for $gpg_error_config_host and thus may not match the
130 *** used host $host.
131 *** You may want to use the configure option --with-libgpg-error-prefix
132 *** to specify a matching config script or use \$SYSROOT.
133 ***]])
134         gpg_config_script_warn="$gpg_config_script_warn libgpg-error"
135       fi
136     fi
137   else
138     GPG_ERROR_CFLAGS=""
139     GPG_ERROR_LIBS=""
140     GPG_ERROR_MT_CFLAGS=""
141     GPG_ERROR_MT_LIBS=""
142     AC_MSG_RESULT(no)
143     ifelse([$3], , :, [$3])
144   fi
145   AC_SUBST(GPG_ERROR_CFLAGS)
146   AC_SUBST(GPG_ERROR_LIBS)
147   AC_SUBST(GPG_ERROR_MT_CFLAGS)
148   AC_SUBST(GPG_ERROR_MT_LIBS)
149 ])