22f8cf92ed2112dded00f98ba08b28893381ab20
[libksba.git] / src / ksba.m4
1 # ksba.m4 - autoconf macro to detect ksba
2 #       Copyright (C) 2002, 2018 g10 Code GmbH
3 #
4 # This file is free software; as a special exception the author gives
5 # unlimited permission to copy and/or distribute it, with or without
6 # modifications, as long as this notice is preserved.
7 #
8 # This file is distributed in the hope that it will be useful, but
9 # WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
10 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
11
12
13 dnl AM_PATH_KSBA([MINIMUM-VERSION,
14 dnl              [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND ]]])
15 dnl Test for libksba and define KSBA_CFLAGS and KSBA_LIBS
16 dnl MINIMUN-VERSION is a string with the version number optionalliy prefixed
17 dnl with the API version to also check the API compatibility. Example:
18 dnl a MINIMUN-VERSION of 1:1.0.7 won't pass the test unless the installed
19 dnl version of libksba is at least 1.0.7 *and* the API number is 1.  Using
20 dnl this features allows to prevent build against newer versions of libksba
21 dnl with a changed API.
22 dnl
23 AC_DEFUN([AM_PATH_KSBA],
24 [ AC_REQUIRE([AC_CANONICAL_HOST])
25   dnl --with-libksba-prefix=PFX is the preferred name for this option,
26   dnl since that is consistent with how our three siblings use the directory/
27   dnl package name in --with-$dir_name-prefix=PFX.
28   AC_ARG_WITH(libksba-prefix,
29               AC_HELP_STRING([--with-libksba-prefix=PFX],
30                              [prefix where KSBA is installed (optional)]),
31      ksba_config_prefix="$withval", ksba_config_prefix="")
32
33   dnl Accept --with-ksba-prefix and make it work the same as
34   dnl --with-libksba-prefix above, for backwards compatibility,
35   dnl but do not document this old, inconsistently-named option.
36   AC_ARG_WITH(ksba-prefix,,
37      ksba_config_prefix="$withval", ksba_config_prefix="")
38
39   if test x$ksba_config_prefix != x ; then
40     if test x${KSBA_CONFIG+set} != xset ; then
41       KSBA_CONFIG=$ksba_config_prefix/bin/ksba-config
42     fi
43   fi
44
45   use_gpgrt_config=""
46   if test x"$KSBA_CONFIG" = x -a x"$GPGRT_CONFIG" != x -a "$GPGRT_CONFIG" != "no"; then
47     if CC=$CC $GPGRT_CONFIG ksba >/dev/null 2>&1; then
48       KSBA_CONFIG="$GPGRT_CONFIG ksba"
49       use_gpgrt_config=yes
50     fi
51   fi
52   if test -z "$use_gpgrt_config"; then
53     AC_PATH_PROG(KSBA_CONFIG, ksba-config, no)
54   fi
55
56   tmp=ifelse([$1], ,1:1.0.0,$1)
57   if echo "$tmp" | grep ':' >/dev/null 2>/dev/null ; then
58      req_ksba_api=`echo "$tmp"     | sed 's/\(.*\):\(.*\)/\1/'`
59      min_ksba_version=`echo "$tmp" | sed 's/\(.*\):\(.*\)/\2/'`
60   else
61      req_ksba_api=0
62      min_ksba_version="$tmp"
63   fi
64
65   AC_MSG_CHECKING(for KSBA - version >= $min_ksba_version)
66   ok=no
67   if test "$KSBA_CONFIG" != "no" ; then
68     req_major=`echo $min_ksba_version | \
69                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
70     req_minor=`echo $min_ksba_version | \
71                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
72     req_micro=`echo $min_ksba_version | \
73                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\3/'`
74     if test -z "$use_gpgrt_config"; then
75       ksba_config_version=`CC=$CC $KSBA_CONFIG --version`
76     else
77       ksba_config_version=`CC=$CC $KSBA_CONFIG --modversion`
78     fi
79     major=`echo $ksba_config_version | \
80                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
81     minor=`echo $ksba_config_version | \
82                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
83     micro=`echo $ksba_config_version | \
84                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`
85     if test "$major" -gt "$req_major"; then
86         ok=yes
87     else
88         if test "$major" -eq "$req_major"; then
89             if test "$minor" -gt "$req_minor"; then
90                ok=yes
91             else
92                if test "$minor" -eq "$req_minor"; then
93                    if test "$micro" -ge "$req_micro"; then
94                      ok=yes
95                    fi
96                fi
97             fi
98         fi
99     fi
100   fi
101   if test $ok = yes; then
102     AC_MSG_RESULT([yes ($ksba_config_version)])
103   else
104     AC_MSG_RESULT(no)
105   fi
106   if test $ok = yes; then
107      # Even if we have a recent libksba, we should check that the
108      # API is compatible.
109      if test "$req_ksba_api" -gt 0 ; then
110         if test -z "$use_gpgrt_config"; then
111           tmp=`CC=$CC $KSBA_CONFIG --api-version 2>/dev/null || echo 0`
112         else
113           tmp=`CC=$CC $KSBA_CONFIG --variable=api_version 2>/dev/null || echo 0`
114         fi
115         if test "$tmp" -gt 0 ; then
116            AC_MSG_CHECKING([KSBA API version])
117            if test "$req_ksba_api" -eq "$tmp" ; then
118              AC_MSG_RESULT(okay)
119            else
120              ok=no
121              AC_MSG_RESULT([does not match.  want=$req_ksba_api got=$tmp.])
122            fi
123         fi
124      fi
125   fi
126   if test $ok = yes; then
127     KSBA_CFLAGS=`CC=$CC $KSBA_CONFIG --cflags`
128     KSBA_LIBS=`CC=$CC $KSBA_CONFIG --libs`
129     ifelse([$2], , :, [$2])
130     if test -z "$use_gpgrt_config"; then
131       libksba_config_host=`CC=$CC $KSBA_CONFIG --host 2>/dev/null || echo none`
132     else
133       libksba_config_host=`CC=$CC $KSBA_CONFIG --variable=host 2>/dev/null || echo none`
134     fi
135     if test x"$libksba_config_host" != xnone ; then
136       if test x"$libksba_config_host" != x"$host" ; then
137   AC_MSG_WARN([[
138 ***
139 *** The config script "$KSBA_CONFIG" was
140 *** built for $libksba_config_host and thus may not match the
141 *** used host $host.
142 *** You may want to use the configure option --with-libksba-prefix
143 *** to specify a matching config script.
144 ***]])
145       fi
146     fi
147   else
148     KSBA_CFLAGS=""
149     KSBA_LIBS=""
150     ifelse([$3], , :, [$3])
151   fi
152   AC_SUBST(KSBA_CFLAGS)
153   AC_SUBST(KSBA_LIBS)
154 ])