build: Make npth.m4 use gpg-error-config.
[npth.git] / npth.m4
1 # npth.m4 - autoconf macro to detect NPTH.
2 # Copyright (C) 2002, 2003, 2004, 2011 g10 Code GmbH
3 #
4 # This file is free software; as a special exception the author gives
5 # unlimited permission to copy and/or distribute it, with or without
6 # modifications, as long as this notice is preserved.
7 #
8 # This file is distributed in the hope that it will be useful, but
9 # WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
10 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
11
12 AC_DEFUN([_AM_PATH_NPTH_CONFIG],
13 [ AC_REQUIRE([AM_PATH_GPG_ERROR])
14   AC_ARG_WITH(npth-prefix,
15             AC_HELP_STRING([--with-npth-prefix=PFX],
16                            [prefix where NPTH is installed (optional)]),
17      npth_config_prefix="$withval", npth_config_prefix="")
18   if test "x$npth_config_prefix" != x ; then
19       NPTH_CONFIG="$npth_config_prefix/bin/npth-config"
20   else
21       NPTH_CONFIG="$GPG_ERROR_CONFIG npth"
22   fi
23
24   if test "$NPTH_CONFIG" != "no" ; then
25     npth_version=`CC=$CC $NPTH_CONFIG --modversion`
26   fi
27   npth_version_major=`echo $npth_version | \
28                sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
29   npth_version_minor=`echo $npth_version | \
30                sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
31 ])
32
33 dnl AM_PATH_NPTH([MINIMUM-VERSION,
34 dnl               [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND ]]])
35 dnl Test for libnpth and define NPTH_CFLAGS and NPTH_LIBS.
36 dnl
37 AC_DEFUN([AM_PATH_NPTH],
38 [ AC_REQUIRE([_AM_PATH_NPTH_CONFIG])dnl
39   tmp=ifelse([$1], ,1:0.91,$1)
40   if echo "$tmp" | grep ':' >/dev/null 2>/dev/null ; then
41      req_npth_api=`echo "$tmp"     | sed 's/\(.*\):\(.*\)/\1/'`
42      min_npth_version=`echo "$tmp" | sed 's/\(.*\):\(.*\)/\2/'`
43   else
44      req_npth_api=1
45      min_npth_version="$tmp"
46   fi
47
48   AC_MSG_CHECKING(for NPTH - version >= $min_npth_version)
49   ok=no
50   if test "$NPTH_CONFIG" != "no" ; then
51     req_major=`echo $min_npth_version | \
52                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
53     req_minor=`echo $min_npth_version | \
54                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
55     if test "$npth_version_major" -gt "$req_major"; then
56         ok=yes
57     else
58         if test "$npth_version_major" -eq "$req_major"; then
59             if test "$npth_version_minor" -gt "$req_minor"; then
60                ok=yes
61             else
62                if test "$npth_version_minor" -eq "$req_minor"; then
63                   ok=yes
64                fi
65             fi
66         fi
67     fi
68   fi
69   if test $ok = yes; then
70     AC_MSG_RESULT([yes ($npth_version)])
71   else
72     AC_MSG_RESULT(no)
73   fi
74   if test $ok = yes; then
75      # If we have a recent NPTH, we should also check that the
76      # API is compatible.
77      if test "$req_npth_api" -gt 0 ; then
78         tmp=`CC=$CC $NPTH_CONFIG --variable=api_version 2>/dev/null || echo 0`
79         if test "$tmp" -gt 0 ; then
80            AC_MSG_CHECKING([NPTH API version])
81            if test "$req_npth_api" -eq "$tmp" ; then
82              AC_MSG_RESULT([okay])
83            else
84              ok=no
85              AC_MSG_RESULT([does not match. want=$req_npth_api got=$tmp])
86            fi
87         fi
88      fi
89   fi
90   if test $ok = yes; then
91     NPTH_CFLAGS=`CC=$CC $NPTH_CONFIG --cflags`
92     NPTH_LIBS=`CC=$CC $NPTH_CONFIG --libs`
93     ifelse([$2], , :, [$2])
94     npth_config_host=`CC=$CC $NPTH_CONFIG --variable=host 2>/dev/null || echo none`
95     if test x"$npth_config_host" != xnone ; then
96       if test x"$npth_config_host" != x"$host" ; then
97         AC_MSG_WARN([[
98 ***
99 *** The config script "$NPTH_CONFIG" was
100 *** built for $npth_config_host and thus may not match the
101 *** used host $host.
102 *** You may want to use the configure option --with-npth-prefix
103 *** to specify a matching config script.
104 ***]])
105       fi
106     fi
107   else
108     NPTH_CFLAGS=""
109     NPTH_LIBS=""
110     ifelse([$3], , :, [$3])
111   fi
112   AC_SUBST(NPTH_CFLAGS)
113   AC_SUBST(NPTH_LIBS)
114 ])