Provide a replacement for socklen_t.
authorWerner Koch <wk@gnupg.org>
Wed, 9 May 2012 13:01:22 +0000 (15:01 +0200)
committerWerner Koch <wk@gnupg.org>
Wed, 9 May 2012 13:01:22 +0000 (15:01 +0200)
* m4/socklen.m4, m4/sys_socket_h.m4: New.
* configure.ac (INSERT_SOCKLEN_T): New.
* src/npth.h.in (INSERT_SOCKLEN_T): New substitution.
(npth_connect, npth_accept): Use _npth_socklen_t.
--

For example SGI IRIX 6.5 MIPS R10000 does not provide socklen_t.  We
provide the usual fallback to int as figured out by a gnulib test.
Note that _npth_socklen_t is internal to nPth and shall not be used by
applications.

configure.ac
m4/socklen.m4 [new file with mode: 0644]
m4/sys_socket_h.m4 [new file with mode: 0644]
src/npth.h.in

index 0c725e1..2eba50c 100644 (file)
@@ -189,6 +189,23 @@ if test x"$ac_cv_header_sys_select_h" = xyes; then
 fi
 AC_SUBST(INSERT_SYS_SELECT_H)
 
+# Some systems lack socklen_t - provide a replacement.
+gl_TYPE_SOCKLEN_T
+case "${host}" in
+  *-*-mingw32*)
+    # socklen_t may or may not be defined depending on what headers
+    # are included.  To be safe we use int as this is the actual type.
+    INSERT_SOCKLEN_T="define _npth_socklen_t int"
+    ;;
+  *)
+    if test ".$gl_cv_socklen_t_equiv" = "."; then
+      INSERT_SOCKLEN_T="define _npth_socklen_t socklen_t"
+    else
+      INSERT_SOCKLEN_T="define _npth_socklen_t ${gl_cv_socklen_t_equiv}"
+    fi
+esac
+AC_SUBST(INSERT_SOCKLEN_T)
+
 
 #
 # Checks for typedefs, structures, and compiler characteristics.
diff --git a/m4/socklen.m4 b/m4/socklen.m4
new file mode 100644 (file)
index 0000000..5e3765a
--- /dev/null
@@ -0,0 +1,52 @@
+# socklen.m4 serial 4
+dnl Copyright (C) 2005, 2006 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl From Albert Chin, Windows fixes from Simon Josefsson.
+
+dnl Check for socklen_t: historically on BSD it is an int, and in
+dnl POSIX 1g it is a type of its own, but some platforms use different
+dnl types for the argument to getsockopt, getpeername, etc.  So we
+dnl have to test to find something that will work.
+
+dnl On mingw32, socklen_t is in ws2tcpip.h ('int'), so we try to find
+dnl it there first.  That file is included by gnulib's socket_.h, which
+dnl all users of this module should include.  Cygwin must not include
+dnl ws2tcpip.h.
+AC_DEFUN([gl_TYPE_SOCKLEN_T],
+  [AC_REQUIRE([gl_HEADER_SYS_SOCKET])dnl
+   AC_CHECK_TYPE([socklen_t], ,
+     [AC_MSG_CHECKING([for socklen_t equivalent])
+      AC_CACHE_VAL([gl_cv_gl_cv_socklen_t_equiv],
+       [# Systems have either "struct sockaddr *" or
+        # "void *" as the second argument to getpeername
+        gl_cv_socklen_t_equiv=
+        for arg2 in "struct sockaddr" void; do
+          for t in int size_t "unsigned int" "long int" "unsigned long int"; do
+            AC_TRY_COMPILE(
+              [#include <sys/types.h>
+               #include <sys/socket.h>
+
+               int getpeername (int, $arg2 *, $t *);],
+              [$t len;
+               getpeername (0, 0, &len);],
+              [gl_cv_socklen_t_equiv="$t"])
+            test "$gl_cv_socklen_t_equiv" != "" && break
+          done
+          test "$gl_cv_socklen_t_equiv" != "" && break
+        done
+      ])
+      if test "$gl_cv_socklen_t_equiv" = ""; then
+       AC_MSG_ERROR([Cannot find a type to use in place of socklen_t])
+      fi
+      AC_MSG_RESULT([$gl_cv_socklen_t_equiv])
+      AC_DEFINE_UNQUOTED([socklen_t], [$gl_cv_socklen_t_equiv],
+       [type to use in place of socklen_t if not defined])],
+     [#include <sys/types.h>
+      #if HAVE_SYS_SOCKET_H
+      # include <sys/socket.h>
+      #elif HAVE_WS2TCPIP_H
+      # include <ws2tcpip.h>
+      #endif])])
diff --git a/m4/sys_socket_h.m4 b/m4/sys_socket_h.m4
new file mode 100644 (file)
index 0000000..d3e45b4
--- /dev/null
@@ -0,0 +1,23 @@
+# sys_socket_h.m4 serial 2
+dnl Copyright (C) 2005, 2006 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl From Simon Josefsson.
+
+AC_DEFUN([gl_HEADER_SYS_SOCKET],
+[
+  AC_CHECK_HEADERS_ONCE([sys/socket.h])
+  if test $ac_cv_header_sys_socket_h = yes; then
+    SYS_SOCKET_H=''
+  else
+    dnl We cannot use AC_CHECK_HEADERS_ONCE here, because that would make
+    dnl the check for those headers unconditional; yet cygwin reports
+    dnl that the headers are present but cannot be compiled (since on
+    dnl cygwin, all socket information should come from sys/socket.h).
+    AC_CHECK_HEADERS([winsock2.h ws2tcpip.h])
+    SYS_SOCKET_H='sys/socket.h'
+  fi
+  AC_SUBST(SYS_SOCKET_H)
+])
index 2110e35..9ad5fb3 100644 (file)
@@ -1,4 +1,5 @@
 /* npth.h - a lightweight implementation of pth over pthread.
+            Configured for: @NPTH_CONFIG_HOST@.
    Copyright (C) 2011, 2012 g10 Code GmbH
 
    This file is part of NPTH.
@@ -52,6 +53,7 @@
 #include <sys/wait.h>
 #include <time.h>
 #include <sys/socket.h>
+#@INSERT_SOCKLEN_T@
 #@INSERT_SYS_SELECT_H@
 
 #include <pthread.h>
@@ -339,8 +341,8 @@ int npth_system(const char *cmd);
 #define npth_sigmask pthread_sigmask
 int npth_sigwait(const sigset_t *set, int *sig);
 
-int npth_connect(int s, const struct sockaddr *addr, socklen_t addrlen);
-int npth_accept(int s, struct sockaddr *addr, socklen_t *addrlen);
+int npth_connect(int s, const struct sockaddr *addr, _npth_socklen_t addrlen);
+int npth_accept(int s, struct sockaddr *addr, _npth_socklen_t *addrlen);
 int npth_select(int nfd, fd_set *rfds, fd_set *wfds, fd_set *efds,
                struct timeval *timeout);
 int npth_pselect(int nfd, fd_set *rfds, fd_set *wfds, fd_set *efds,